Sound

Бесплатный MP3 Flash Плеер

admin — Wed, 04 Feb 2009 02:33:09 +0300

MP3 Flash Player нужен каждому

Теперь вы без лишних усилий можете скачать и установить себе на сайт вот такой бесплатный MP3 Flash плеер. За пользование плеером, просьба оставлять прямую ссылку на сайт, что-то типо этого: http://www.flashist.ru/, ну и по возможности комментарий в этой теме =)

Проще простого

Всё, что вам нужно, так это выбрать наиболее подходящий для вас html код из представленных в readme файле и скопировать его к себе. Грубо говоря, я использую только 2 способа: SWF OBJECT и Object/Embed. Первый является более гибким и удобным, на мой взгляд, но существует ряд случаев, когда его использование не возможно, например, если вы хотите встроить плеер к себе в ЖЖ. Одним из преимуществ SWF OBJECT метода является возможность показать альтернативное содержание (картинки или текст) пользователям, у которых не установлен Flash Player нужной версии.

На самом деле я уверен, что не все разберутся с установкой MP3 Flash плеера без проблем, поэтому пишите свои вопросы в этой теме. Для удобства пользования я сделал два архива к плееру. Первый архив содержит только .swf файл флешки, .html страницы, в которую уже встроен проигрыватель и readme.txt, в котором я ещё кратко объяснил все способы встраивания плеера на сайт. Во второй архив, был добавлен ещё MP3 файл, который вы можете использовать в тестировании плеера.

Параметры плеера:

1. Flash Player 7 версии;
2. Ширина 200px;
3. Высота 50px.

ОБЯЗАТЕЛЬНО ПРОЧТИТЕ README ФАЙЛ.

MP3 файл, который вы хотите проиграть с помощью плеера обязательно должен быть выложен в сети и иметь прямую ссылку. Как вариант, файлы можно заливать на Music.Lib. Всякие файлообменники, типо Rapidshare и iFolder не подходят, т.к. они не дают прямой ссылки на файл.

Плеер в действии » | Архив #1 » | Архив #2 »

P.S.:

Если интересно, то как работает плеер в LiveJournal,

Учимся работать со звуком

admin — Thu, 05 Feb 2009 02:34:38 +0300

Потоковое/Не потоковое аудио

Во Flash предусмотрены возможности работы как с потоковым, так и с не потоковым аудио. Для начала разберём, как создаются объекты Sound:

var url_sound:Sound = new Sound();

Собственно вот мы и создали объект url_sound. Обратите внимание, что _sound — это суффикс объектов класса Sound, как и _mc для Movie Clip, и _txt для Text Field. Ещё раз напоминаю, на всякий случай, что суффиксы позволяют упростить и ускорить набор кода, т.к. автоматически выдают список всех встроенных функций и методов после точки «.» поставленной за нужным суффиксом.

Загрузка аудио файлов через loadSound

loadSound(URL,isStreaming)

1. URL — адрес подгружаемого аудио файла;
2. isStreaming — флаг, показывающий будет подгружаемое аудио потоковым или обычным. Может принимать значения либо true, либо flase. Потоковое — true. Обычное — false. Основной особенностью потокового аудио является то, что мы можем начать его прослушивание до полной загрузки файла. Например на всем известном MySpace используется именно потоковое аудио.

Основные свойства и методы Sound объектов во Flash

1. getBytesLoaded() — показывает сколько байт уже загрузилось;
2. getBytesTotal() — показывает общий размер аудио файла. К слову ,чтобы узнать сколько байт ещё осталось загрузить, нужно просто из второго параметра вычесть первый:

trace(“Осталось загрузить ещё байт “+(url_sound.getBytesTotal()-url_sound.getBytesLoaded()));

3. position — показывает в миллисекундах время проигрываемого сейчас фрагмента:

trace(“Сейчас проигрывается секунда номер “+(url_sound.position/1000));

4. duration — показывает общую продолжительность аудио файла в миллисекундах. Работая с потоковым аудио, следует учитывать, что duration показывает длительность уже загруженного фрагмента файла, а не общую продолжительность файла. Т.е. если длина вашего файла 10 секунд, а вы загрузили только 3 секунды, то duration будет показывать значение 3000. Примерную длину аудио файла можно вычислить следующим образом:

trace(“Общая длина файла примерно “+(url_sound.duration*getBytesTotal()/getBytesLoaded()/1000)+” секунд”);

5. start(secondsOffset,loops) — начинает воспроизведение файла. В случае с потоковым аудио, воспроизведение начинается автоматически после начала загрузки. secondsOffset — с какой секунды нужно начать воспроизведение. Указывается именно в секундах. loops — количество повторов воспроизведения трека. Так же можно использовать сокращённую запись start();
6. stop() — останавливает воспроизведение.

Подключаем звук из библиотеки

Так же есть возможность работать со звуком напрямую из вашей библиотеки Library. Для этого нужно использовать следующую запись:

lib_sound.attachSound(idName)

1. lib_sound — это имя Sound объекта, к которому мы прикрепляем нужный аудио файл из библиотеки. Сам объект lib_sound должен быть предварительно создан;
2. attachSound(idName) — метод прикрепляющий из библиотеки нужный файл. idName — это имя звука, которое задаётся во вкладке Linkage (выбираем нужный объект в библиотеке и жмём на него правой кнопкой мыши).

Когда проигрывание закончилось Для того, чтобы отловить окончание воспроизведения файла, существует событие onSoundComplete. Например, следующая запись будет запускать сначала воспроизведение файла, сразу после окончания:

url_sound.onSoundComplete = function() {
        trace(“Трек закончился и начинает проигрываться заново”);
        this.start();
};

Описание получилось очень большим, но вроде, понятным, поэтому всё, что мне остаётся, так это выложить исходник и пример к уроку =)

Сама флешка » | Исходник »

Плавное включение/выключение звука во Flash

admin — Sun, 08 Feb 2009 16:23:39 +0300

Урок по включению/выключению звука в Flash

В этом уроке речь пойдёт о том, как организовать плавное включение/выключение звука во Flash. Опять же, просто нужно знать, какие методы использовать в вашей флешке. Основными методами урока будут getVolume() и setVolume(number), с помощью которых можно узнать текущее и установить новое значение громкости для Sound объекта в Flash.

Как же это всё организовать в флешке?

Для начала давайте разберём в двух словах, как это всё работает. Первым делом нужно понять, что «плавное» — это означает не мгновенное, а постепенное изменение какого-то свойства, в данном случае громкости. Таким образом, нам нужно будет не сразу изменить значение громкости на 0, если мы выключаем звук, а создать функцию, которая бы при вызове уменьшала значение громкости на какое-то число, и вызывать эту функцию до того момента, пока громкость не упадёт до нуля. Я не буду разбирать в этой статье, как во Flash создаются Sound объекты, т.к. об этом вы можете прочитать в статье «Учимся работать со звуком».

Необходимые функции:

function soundOn_func(varDelta:Number) {
        _root.s_sound.setVolume(_root.s_sound.getVolume()+varDelta);
        if (_root.s_sound.getVolume()>=100) {
                clearInterval(_root.sound_int);
                _root.s_sound.setVolume(100);
        }
}

1. soundOn_func — имя функции, которая будет постепенно увеличивать громкость звука в Flash;
2. varDelta — число, на которое каждый раз при запуске функции будет увеличиваться громкость Sound объекта. Конечно, его можно было бы задать и вручную без всяких переменных, но такой способ, когда в теле функции прописывают необходимую переменую и потом с ней работают, гораздо более гибкий;
3. setVolume(_root.s_sound.getVolume()+varDelta) — здесь мы непосредственно прибавляем к текущему значению громкости переменную varDelta. setVolume(number) — это функция, которая устанавливает значение громкости звука для Sound объекта в Flash. Функция getVolume() возвращает нам текущее значение громкости звука. Запомните, что громкость может изменяться от 0 до 100, где 0 — звук выключен полностью, а 100 — максимальная громкость. Так же нужно запомнить, что если громкость будет ниже 0, то звук будет слышен, причём, чем дальше от 0 будет значение, тем громче он будет.

Вот и всё, теперь нам нужно просто создавать интервал, вызывающий эту функцию каждый раз, когда мы захотим плавно увеличить громкость. Делается это примерно следующим образом:

_root.sound_int = setInterval(_root.soundOn_func, 50, 10);

1. _root.sound_int — переменная интервала, по которой потом к можно будет обращаться к интервалу;
2. _root.soundOn_func — имя функции, которая будет вызываться с определённым интервалом;
3. 50 — время, через которое будет вызываться функция. Указывается в миллисекундах (0.001 сек.). Означает, что функция будет вызываться 20 раз в секунду (1000/50=20);
4. 10 — передаваемая в вызываемую функцию переменная. У нас это, если вы ещё не забыли, переменная varDelta.

Вот, собственно, всё и готово к использованию, если у объекта s_sound громкость будет меньше 100, то при вызове функции его громкость будет постепенно увеличится, если громкость будет равна 100, то громкость будет постепенно уменьшаться.

Сама флешка » | Архив »

Меняем громкость и кидаем по каналам звук в Flash

admin — Mon, 09 Feb 2009 02:00:35 +0300

[CUT]Урок о том, как в Flash пускать звук в левый/правый канал, а так же, как работать с громкостью звука.[/CUT]

Sound объекты в Flash

Вот сделал урок, в которым объясняется как менять громкость в ваших Flash приложениях, и как в флешках работать с левым / правым каналом *…ну, допустим, включить только левую колонку…*. Главные действующие лица это объекты Sound, а так же функции setVolume(number) и setPan(number).

Громкость флешек

Допустим вы хотите сделать MP3 Flash плеер для своего сайта. Согласитесь, хорошо было бы дать пользователю возможность выбирать громкость прослушиваемой музыки. Вот тут то нам на помощь и приходят два метода getVolume() и setVolume(number), первый — показывают нам текущий уровень громкости музыки, в то время, как второй — даёт возможность установить новое значение для громкости проигрываемого звука. О том, как создавать Sound объекты в Flash, я надеюсь, вы уже знаете, поэтому можно просто перейти к знакомству с фукнциями.

Функции необходимые для изменения уровня громкости звука в Flash

1. setVolume(number) — как уже говорилось выше, эта функция устанавливает для нашего звукового объекта нужный уровень громкости. Переменная number и является значением громкости, которую нужно установить. И вообще, громкость звука в Flash может варьироваться от 0 до 100, где 0 — это вообще не слышно, а 100 — звук играет на полную громкость. В принципе, вы можете установить звук и на -100 (минус сто), и на +1000, но это уже будет на вашей совести =) Адекватной работы в этом случае не обещаю. При большом увеличении звук обычно начинает хрипеть, а при громкости звука в флешках меньше 0, он опять становиться слышен, пропорционально уменьшению. Поэтому, громкость со значением -1 будет идентична громкости со значением +1.
2. getVolume() — возвращает нам всё то же значение громкости звука во Flash.

Работа с левым и правым каналом звука

Думаю никому объяснять не надо, что такое возможность переключать звук на левый/правый канал. Так вот, эту же возможность можно реализовать и во Flash. «Как», - спросите вы. «Очень просто», - отвечу я =)

1. setPan(number) — устанавливает балланс для нашего звука в Flash. Значение числа number может варьироваться от -100 до 100, где -100 — это звук полностью перешёл на левый канал, а 100 — звук полностью на правом. Ну и соответственно, 0 (ноль) — это, когда на оба канала идёт одинаковая громкость. По-умолчанию, установлен как раз 0. Если вы пытаетесь воспользоваться данной функцией, и у вас выходит совсем не то что нужно, например, при -100 звук идёт не в левый канал, а в правый, и наоборот, то проверьте всё на стандартном Windows’ском регуляторе (два раза клацните на значке динамика в правом нижнем углу вашего рабочего стола, если этот значёк у вас есть там). Если у вас при регулировке каналов получается "обратная" реакция, то проверьте правильно ли у вас подключены колонки/наушники.
2. getPan() — возвращает нам значение установленного балланса для звукового объекта в флешке. Как было сказано выше, значение, за частую варьируется от -100 до 100. Кстати да, как и в случае с громкостью, вы можете экспериментировать и устанавливать на свой страх и риск значения меньше -100 (минус ста) и больше 100, но в этом случае хрипоты и большой нагрузки на колонки вам, пожалуй, не избежать.

Теперь можно всё опробовать в деле

Собственно вот и всё =) В примере, для наглядности, был использован вывод уровня громкости в текстовое поле, а так же, из Movie Clip’ов было сделано два регулятора громкости, так что всё, надеюсь, должно быть понятно и удобно. В общем, как обычно качаем исходник и смотрим в код, если что не понятно, то оставляем свои комментарии прямо тут.

Всем удачи =)

Сама флешка » | Исходник »

Синхронное воспроизведение звуков

admin — Wed, 25 Feb 2009 22:41:36 +0300

[CUT]Сегодня мы разберём с вами, как можно организовать синхронное воспроизведение звуков, чтобы, если 1 звук играл-играл и остановился на каком-то месте, другой звук начинал своё воспроизведение с той же минуты/секунды, на котором остановился предыдущий звук.[/CUT]

Синхронное воспроизведение звуков

Сегодня мы разберём с вами, как можно организовать синхронное воспроизведение звуков, чтобы, если 1 звук играл-играл и остановился на каком-то месте, другой звук начинал своё воспроизведение с той же минуты/секунды, на котором остановился предыдущий звук. В качестве инструмента программирования мы будем использовать ActionScript 2.0

История вопроса

Этот вопрос уходит своими корнями в далёкое прошлое, когда в рубрике «Вопрос-ответ» был задан вопрос о синхронизации звука. Автор этого вопроса, спрашивал, цитирую:

Цитата:

Вопрос следующий: Представте...сидит оркестр, как сделать, что бы при нажатии на любой инструмент он начинал исполнять
свою партию!А если на следующие другие, то они должны включаться в том же месте где играет первый!!!

И некто, admin помог ему в решении этого вопроса. А теперь, возможность узнать ответ на него есть и у вас =)

Что нам нужно?

Нам нужно создать в .fla проекте 2 кнопки с именами sound1_mc и sound2_mc, а потом импортировать в библиотеку проекта, 2 звука, с именами sound1 и sound2. Эти имена звуков обязательно должны быть указаны в вкладке Linkage, а так же, необходимо будет поставить галочки напротив надписей «Export for ActionScript» и «Export in first frame».

Половина дела сделана, теперь осталось написать код программы =)

Необходимая функция

Так, как мы будем работать со звуком, нам придётся работать с объектами Sound, которые и отвечают в Flash за работу со звуком. Ключевой функцией, которую мы будем использовать в нашем уроке станет функция, которая запускает проигрывание звуков:

_sound.start(_number);

Где, _sound — это объект Sound, а _number — это цифровое значение в миллисекундах, с которого начнётся проигрывание звука.

Код программы

Stage.scaleMode = "noScale";
Stage.align = "TL";
//
var my1_sound:Sound = new Sound(this.sound1_mc);
my1_sound.attachSound("sound1");
var my2_sound:Sound = new Sound(this.sound2_mc);
my2_sound.attachSound("sound2");
//Делаем, чтобы когда мелодия начинала проигрываться заново при окончании
my1_sound.onSoundComplete = my2_sound.onSoundComplete=function () {
	this.start();
};
//Создаём переменную, в которую будем запоминать, какой сейчас играет звук
var current_sound:Sound;
//Запоминаем, какой звук соответствует какой кнопке
this.sound1_mc.var_sound = my1_sound;
this.sound2_mc.var_sound = my2_sound;
//
//Создаём обработчик события onRelease, каждый раз при его срабатывании
//будет запускаться функция _root.changeCound_func, в которую будет
//передаваться параметр this.var_sound. Эти параметры мы присвоили кнопкам
//чуть выше
this.sound1_mc.onRelease = this.sound2_mc.onRelease = function() {
	_root.changeCound_func(this.var_sound);
};
//
function changeCound_func(new_sound:Sound) {
	trace("Запускаем новый звук");
	//Создаём переменную, в которую будем запоминать, на какой позиции сейчас
	//находится играющий звук
	var _soundPos:Number
	//Если до этого какой-нибудь звук был запущен, то присваеваем позицию,
	//на которой находится этот звук переменной
	if(_root.current_sound){
		_soundPos = _root.current_sound.position;
	}else{
		//Если никакого звука до этого не было запущено, то начинаем
		//проигрывание с 0
		_soundPos = 0;
	}
	trace("Начинаем проигрывать с позиции "+_soundPos);
	//Останавливаем предыдущий звук
	_root.current_sound.stop();
	//Включаем следующий звук. Деление на 1000 нужно потому, что свойство position задаётся в
	//миллисикундах, а в фукнцию start время старта проигрывания передаётся в секундах.
	new_sound.start(_soundPos/1000);
	//Запоминаем новый звук, в переменной current_sound, потому что теперь
	//он проигрывается
	_root.current_sound = new_sound;
}

Не поверите, но вот и всё. По-идее, у вас должна была получиться такая же работающая флешка, как и у меня, где при нажатии на одну из кнопок, начинал проигрываться звук с того места, на котором закончил играть предыдущий звук.

Если у вас что-то не получилось, то вы всегда сможете скачать исходник и посмотреть, как всё было реализовано.

Сама флешка | Исходник

Удачи вам =)